Comment accéder en direct aux données de mesure en utilisant le Modbus

Saviez-vous que vous pouviez transformer votre centrale d'acquisition de données Campbell Scientific en une esclave Modbus TCP/IP ? Savez-vous pourquoi c'est une bonne idée ? Les centrales de mesure de Campbell Scientific sont couramment utilisées comme des automates Modbus esclaves. Cela signifie que la centrale d'acquisition de données est configurée pour mettre en œuvre le protocole de communication Modbus et répondre aux requêtes Modbus d'un appareil Modbus client, comme un SCADA (supervisory control and data acquisition) du système. Transformer votre centrale de mesure en serveur Modbus TCP/IP est un excellent moyen pour permettre aux systèmes qui utilisent le protocole Modbus d'avoir accès à vos données de mesure en direct.

Pour mieux comprendre comment cela fonctionne, nous allons vous montrer un exemple d'exercice, afin de vous faire découvrir les concepts de base pour mettre en œuvre le protocole Modbus sur une centrale d'acquisition de données CR1000. Nous allons utiliser une centrale de mesure CR1000 connectée à un système SCADA. Vous pouvez relire notre précédente page sur les systèmes SCADA et le Modbus dans l'article du blog ''Introduction au Modbus".

Commençons

Dans notre exemple, la CR1000 est programmée pour mesurer la tension de la batterie, la température du bornier, et une mesure analogique dans un programme simple comme indiqué ci-dessous :

'Programme pour une centrale de mesure CR1000

'Déclaration des variables Public 
Public PTemp, batt_volt, analog_meas

'Définition des tables de données
DataTable (Table1,1,-1) 
	DataInterval (0,10,Min,10)
	Minimum (1,batt_volt,FP2,0,False)
	Average (1,PTemp,FP2,False)	
	Average (1,analog_meas,FP2,False)
EndTable

'Programme principal
BeginProg
	Scan (1,Sec,0,0)
		'Mesure la température du bornier de la centrale de mesure
		PanelTemp (PTemp,250)
		
		'Mesure la tension de la batterie
		Battery (batt_volt)
		
		'Mesure une tension analogique
		VoltSe (analog_meas,1,mV5000,1,1,0,_60Hz,1.0,0)
		
		'Appel de la table pour le stockage des données
		CallTable Table1
	NextScan
EndProg

Programmation Modbus

Dans notre exemple, la centrale d'acquisition de mesures CR1000 est connectée à un système de supervision en utilisant une Interface Ethernet NL121. Par conséquent, nous avons besoin de programmer votre centrale d'acquisition de données pour recevoir les requêtes Modbus sur le port de communication approprié et de répondre en envoyant les données mesurées les plus récentes. Pour faire cela, nous avons besoin de l'instruction ModbusServer(), de déclarer un tableau de variables pour contenir nos données Modbus, puis mettre à jour ce tableau avec les mesures.

Ceci est réalisé en utilisant le code ci-dessous :

'Programme pour une centrale de mesure CR1000

'Déclaration des variables Public  
Public PTemp, batt_volt, analog_meas 
Public ModbusVariable(3) 
Public DummyVar As Boolean 

'Data Table Definition 
DataTable (Table1,1,-1) 
DataInterval (0,10,Min,10) 
     Minimum (1,batt_volt,FP2,0,False) 
     Average (1,PTemp,FP2,False) 
     Average (1,analog_meas,FP2,False) 
EndTable 

'Programme principal 
BeginProg

'Configuration de la centrale de mesure en server Modbus
ModbusServer (502,115200,1,ModbusVariable,DummyVar,0)

     Scan (1,Sec,0,0)
          'Mesure la température du bornier de la CR1000
           PanelTemp (PTemp,250)
 
          'Mesure la tension de la batterie 
           Battery (batt_volt)

          'Mesure une tension analogique
           VoltSe (analog_meas,1,mV5000,1,1,0,_60Hz,1.0,0)

          'Affectation des registres Modbus
           ModbusVariable(1) = PTemp
           ModbusVariable(2) = batt_volt
           ModbusVariable(3) = analog_meas

          'Appel de la table pour le stockage des données 
           CallTable Table1
 
     NextScan
EndProg

Remarque : pour la compréhension du programme, les accents ont été rajoutés 
dans les commentaires. Dans l'éditeur CRBasic, il n'est pas possible d'ajouter 
des accents dans les commentaires.

Regardons de plus près !

Jetons un coup d'œil de plus près à l'instruction ModbusServer() que nous avons ajouté au programme. L'instruction a été ajoutée entre BeginProg et l'instruction Scan. L'instruction ModbusServer() est placée entre ces deux instructions, car elle ne doit s'exécuter qu'une fois au moment de la compilation plutôt que d'être exécutée pendant chaque échantillonnage ou scrutation (Scan). 

L'instruction ModbusServer() contient les 6 paramètres suivants :

ModbusServer (COMPort,BaudRate,ModbusAddr,ModbusVariable,BooleanVar,ModbusOption)

Pour mémoire, dans notre programme, notre instruction avec les paramètres ressemble à ceci :

ModbusServer (502,115200,1,ModbusVariable,DummyVar,0)

Jetons un coup d'oeil de plus près à ces paramètres et ce qu'ils signifient :

• COMPort : Ce paramètre définit le port de communication sur lequel la centrale d'acquisition de données reçoit les requêtes Modbus. Dans notre exemple, nous utilisons 502, parce que nous utilisons une connexion Ethernet et 502 est le port Modbus TCP par défaut.
  
  
• BaudRate : Nous utilisons ce paramètre pour régler la vitesse de communication du port en bauds. Dans notre exemple, ce paramètre (115200) est ignoré parce que vos communications sont sur une connexion Ethernet.

• ModbusAddr : Ce paramètre configure l'adresse Modbus de la centrale de mesure. Dans notre exemple, nous configurons l'adresse de la centrale d'acquisition à 1.
  
  
• ModbusVariable : Nous utilisons ce paramètre pour définir la carte Modbus de notre centrale d'acquisition de données. (Une carte Modbus définit les adresses des registres pour les données disponibles.)
  
  Les mesures stockées dans ce tableau sont utilisées comme entrée Modbus et maintenues dans des registres. (Un registre est un emplacement mémoire de 16 bits.) La centrale d'acquisition de données ne permet pas de distinguer entre l'entrée et les registres d'exploitation. Parce que nous avons déclaré notre variable Modbus comme un nombre à virgule flottante (32 bits), elle sera répartie sur deux registres Modbus (16 bits de chaque). Dans notre exemple, notre carte Modbus ressemble à ceci :
  
  

  Registres Modbus	Description des mesures	Unités
  1,2	Température du bornier du Datalogger	Degrés Celsius
  3,4	Tension batterie du Datalogger	Volts
  5,6	Mesure analogique	Millivolts

• ModbusBooleanVar : Ce paramètre contient le résultat si un automate ou SCADA client Modbus envoie une commande Marche / Arrêt à la centrale de mesure pour les ports de contrôle par exemple (C'est, 01 Lire l'état de la Bobine/Port, 02 Lire l'état de l'entrée, 05 Activer la Bobine/Port, 15 Activer de multiples Bobines/Ports).
  
  Si un 0 est entré dans ces paramètres, les commandes discrètes sont mappés sur les ports de contrôle C1 à C8 de la centrale d'acquisition de données, et un avertissement du compilateur est généré. Dans notre exemple, J'ai créé une variable fictive pour éviter le scénario suivant : la cartographie des commandes à partir d'un dispositif maître pour contrôler les ports et la génération d'un avertissement du compilateur.
  
  
• ModbusOption : Ceci est un paramètre optionnel qui définit le type de données des variables Modbus et l'ordre des octets. Dans notre exemple, j'ai choisi de formater vos variables Modbus à virgule flottante avec l'ordre des octets inversés (CDAB).

Conclusion

L'exemple ci-dessus décrit la façon dont vous pouvez accomplir une implémentation simple serveur Modbus TCP/IP par la programmation d'une centrale d'acquisition de données CR1000 dans CRBasic. Veuillez noter que l'éditeur de programme Short Cut a aussi la possibilité de générer le code ci-dessus. En tirant parti des concepts présentés ci-dessus, vous pouvez ajouter d'autres mesures à votre programme, ainsi que la carte Modbus de votre centrale de mesure. Le résultat est que votre système SCADA peut accéder aux données de mesure en direct pour recevoir les données d'une station météo, ou d'un système de mesure d'ouvrage d'art pour le génie civil.

Vous pouvez vous attendre à un autre article du blog à l'avenir avec plus de détails sur des sujets Modbus spécifiques, les pièges courants et les meilleures pratiques. Pendant ce temps, partager vos commentaires et vos questions sur le Modbus ci-dessous.